# Maintainer: Fredy García <frealgagu at gmail dot com>

pkgname=habitica-nativefier
pkgver=1.0
pkgrel=1
pkgdesc="Habitica built with nativefier (electron)"
arch=("armv7l" "i686" "x86_64")
url="https://habitica.com"
license=("custom")
depends=("gtk3" "libxss" "nss")
optdepends=("libindicator-gtk3")
makedepends=("imagemagick" "nodejs-nativefier" "unzip")
source=(
  "${pkgname}.png"
  "${pkgname}.desktop"
)
sha256sums=(
  "e5d94d5e9388ba75734e50b0570aa4bbd47dac20143593cee856a2b7fda690c9"
  "9cf409caa77059151fd8cf2db8fbae8ee16cbccb9012d04dee7195e201e348df"
)

build() {
  cd "${srcdir}"

  nativefier \
    --name "Habitica" \
    --icon "${pkgname}.png" \
    --width "800px" \
    --height "600px" \
    --user-agent "Mozilla/5.0 (X11; Linux x86_64) AppleWebKit/605.1.15 (KHTML, like Gecko) Version/15.4 Chrome/102.0.0.0 Safari/605.1.15" \
    --verbose \
    --single-instance \
    "${url}"
}

package() {
  install -dm755 "${pkgdir}/"{opt,usr/{bin,share/{applications,licenses/${pkgname}}}}

  _folder=$(ls "${srcdir}" | grep "[Hh]abitica-linux-")
  _binary=$(ls "${srcdir}/${_folder}" | grep "[Hh]abitica")

  cp -rL "${srcdir}/${_folder}" "${pkgdir}/opt/${pkgname}"
  ln -s "/opt/${pkgname}/${_binary}" "${pkgdir}/usr/bin/${pkgname}"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -Dm644 "${pkgdir}/opt/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  for _size in "192x192" "128x128" "96x96" "64x64" "48x48" "32x32" "24x24" "22x22" "20x20" "16x16" "8x8"; do
    install -dm755 "${pkgdir}/usr/share/icons/hicolor/${_size}/apps"
    convert "${srcdir}/${pkgname}.png" -strip -resize "${_size}" "${pkgdir}/usr/share/icons/hicolor/${_size}/apps/${pkgname}.png"
  done
}